Arduino Denge Robotu Nasıl Yapılır?

Arduino Denge Robotu Nasıl Yapılır?
113,750 views
1,643   

Bu projede, kendini dengeleyen ve devrilmeyen bir Arduino Denge (Balance) Robotunun nasıl yapılacağını öğreneceğiz.

Gerekli Bileşen ve Donanım

Robot Montajı

  • 3 Akrilik Levha’nın dört köşesini delin.
  • Her akrilik tabaka arasında ki mesafe yaklaşık 8 santimetre olacaktır.
  • Robot Boyutları (yaklaşık) 15 cm x 10 cm x 20 cm
  • DC motor ve tekerlekler, robotun merkezine (orta hatta) yerleştirilecektir.
  • L298N Motor Sürücü, robotun birinci kat merkezine (orta hatta) yerleştirilecektir.
  • Arduino geliştirme kartı robotun ikinci katına yerleştirilecek.
  • MPU6050 sensörü, robotun en üst katında yer alacaktır.

Bağlantılar

MPU6050’yi test edin ve çalıştığından emin olun! MPU6050’yi önce Arduino’ya bağlayın ve aşağıdaki öğreticide bulunan kodları kullanarak çalıştığını test edin. Veriler seri monitörde görüntülenmelidir.

34,972 views
396   

 

Dengeleme Nasıl Çalışır?

  • Robotu dengeli tutmak için motorlar robotun düşüşüne karşı koymalıdır.
  • Bu eylem, bir geri besleme ve bir düzeltme elemanı gerektirir.
  • Geri besleme elemanı, Arduino tarafından robotun mevcut yönünü bilmesi için kullanılan üç eksende hem hızlanma hem de dönüş sağlayan MPU6050’dir.
  • Düzeltme elemanı motor ve tekerlek kombinasyonudur.
  • Kütle merkezi tekerlek akslarına göre daha yüksekse daha iyi dengelenebilir. Bu yüzden bataryayı robot iskeletinin en üst katına yerleştirdim. 

Kaynak Kodu ve Kütüphaneler

Denge robotu için geliştirilen kod çok karmaşıktır. Ama endişelenmenize gerek yok. Sadece bazı verileri değiştireceğiz. Kodu çalıştırmak için dört adet harici kütüphaneye ihtiyacımız var.

  • PID kütüphanesi P, I ve D değerlerini hesaplamayı kolaylaştırır.
  • LMotorController kütüphanesi, iki motoru L298N modülü ile sürmek için kullanılır.
  • I2Cdev kitaplığı ve MPU6050_6_Axis_MotionApps20 kitaplığı MPU6050’den veri okumak içindir.

Kütüphanelere aşağıdaki bağlantılardan ulaşabilirsiniz.

#include <PID_v1.h>
#include <LMotorController.h>
#include "I2Cdev.h"
#include "MPU6050_6Axis_MotionApps20.h"

#if I2CDEV_IMPLEMENTATION == I2CDEV_ARDUINO_WIRE
 #include "Wire.h"
#endif

#define MIN_ABS_SPEED 30

MPU6050 mpu;

// MPU control/status vars
bool dmpReady = false; // set true if DMP init was successful
uint8_t mpuIntStatus; // holds actual interrupt status byte from MPU
uint8_t devStatus; // return status after each device operation (0 = success, !0 = error)
uint16_t packetSize; // expected DMP packet size (default is 42 bytes)
uint16_t fifoCount; // count of all bytes currently in FIFO
uint8_t fifoBuffer[64]; // FIFO storage buffer

// orientation/motion vars
Quaternion q; // [w, x, y, z] quaternion container
VectorFloat gravity; // [x, y, z] gravity vector
float ypr[3]; // [yaw, pitch, roll] yaw/pitch/roll container and gravity vector

//PID
double originalSetpoint = 172.50;
double setpoint = originalSetpoint;
double movingAngleOffset = 0.1;
double input, output;

//adjust these values to fit your own design
double Kp = 60;   
double Kd = 2.2;
double Ki = 270;
PID pid(&input, &output, &setpoint, Kp, Ki, Kd, DIRECT);

double motorSpeedFactorLeft = 0.6;
double motorSpeedFactorRight = 0.5;

//MOTOR CONTROLLER
int ENA = 5;
int IN1 = 6;
int IN2 = 7;
int IN3 = 9;
int IN4 = 8;
int ENB = 10;
LMotorController motorController(ENA, IN1, IN2, ENB, IN3, IN4, motorSpeedFactorLeft, motorSpeedFactorRight);

volatile bool mpuInterrupt = false; // indicates whether MPU interrupt pin has gone high
void dmpDataReady()
{
 mpuInterrupt = true;
}


void setup()
{
 // join I2C bus (I2Cdev library doesn't do this automatically)
 #if I2CDEV_IMPLEMENTATION == I2CDEV_ARDUINO_WIRE
 Wire.begin();
 TWBR = 24; // 400kHz I2C clock (200kHz if CPU is 8MHz)
 #elif I2CDEV_IMPLEMENTATION == I2CDEV_BUILTIN_FASTWIRE
 Fastwire::setup(400, true);
 #endif

 mpu.initialize();

 devStatus = mpu.dmpInitialize();

 // supply your own gyro offsets here, scaled for min sensitivity
 mpu.setXGyroOffset(220);
 mpu.setYGyroOffset(76);
 mpu.setZGyroOffset(-85);
 mpu.setZAccelOffset(1788); // 1688 factory default for my test chip

 // make sure it worked (returns 0 if so)
 if (devStatus == 0)
 {
 // turn on the DMP, now that it's ready
 mpu.setDMPEnabled(true);

 // enable Arduino interrupt detection
 attachInterrupt(0, dmpDataReady, RISING);
 mpuIntStatus = mpu.getIntStatus();

 // set our DMP Ready flag so the main loop() function knows it's okay to use it
 dmpReady = true;

 // get expected DMP packet size for later comparison
 packetSize = mpu.dmpGetFIFOPacketSize();
 
 //setup PID
 pid.SetMode(AUTOMATIC);
 pid.SetSampleTime(10);
 pid.SetOutputLimits(-255, 255); 
 }
 else
 {
 // ERROR!
 // 1 = initial memory load failed
 // 2 = DMP configuration updates failed
 // (if it's going to break, usually the code will be 1)
 Serial.print(F("DMP Initialization failed (code "));
 Serial.print(devStatus);
 Serial.println(F(")"));
 }
}


void loop()
{
 // if programming failed, don't try to do anything
 if (!dmpReady) return;

 // wait for MPU interrupt or extra packet(s) available
 while (!mpuInterrupt && fifoCount < packetSize)
 {
 //no mpu data - performing PID calculations and output to motors 
 pid.Compute();
 motorController.move(output, MIN_ABS_SPEED);
 
 }

 // reset interrupt flag and get INT_STATUS byte
 mpuInterrupt = false;
 mpuIntStatus = mpu.getIntStatus();

 // get current FIFO count
 fifoCount = mpu.getFIFOCount();

 // check for overflow (this should never happen unless our code is too inefficient)
 if ((mpuIntStatus & 0x10) || fifoCount == 1024)
 {
 // reset so we can continue cleanly
 mpu.resetFIFO();
 Serial.println(F("FIFO overflow!"));

 // otherwise, check for DMP data ready interrupt (this should happen frequently)
 }
 else if (mpuIntStatus & 0x02)
 {
 // wait for correct available data length, should be a VERY short wait
 while (fifoCount < packetSize) fifoCount = mpu.getFIFOCount();

 // read a packet from FIFO
 mpu.getFIFOBytes(fifoBuffer, packetSize);
 
 // track FIFO count here in case there is > 1 packet available
 // (this lets us immediately read more without waiting for an interrupt)
 fifoCount -= packetSize;

 mpu.dmpGetQuaternion(&q, fifoBuffer);
 mpu.dmpGetGravity(&gravity, &q);
 mpu.dmpGetYawPitchRoll(ypr, &q, &gravity);
 input = ypr[1] * 180/M_PI + 180;
 }
}

PID, Kp, Ki ve Kd değerlerinin optimal değerlere “ayarlı” olmasını gerektirir.

PID değerlerini manuel olarak ayarlayacağız.

  1. Kp, Ki ve Kd‘yi sıfıra eşit yapın.
  2. Kp‘yi ayarlayın. Çok az Kp robotun devrilmesine neden olur (yeterli düzeltme olmadığı için). Çok fazla Kp robotu dengesizce hareketine neden olur. Yeterince iyi bir Kp, robotu hafifçe ileri geri hareket ettirecektir (ya da biraz sallanacaktır).
  3. Kp ayarlandıktan sonra Kd ayarını yapın. İyi bir Kd değeri, robot neredeyse sabit olana kadar salınımları azaltacaktır. Ayrıca, doğru miktarda Kd, ittirildiğinde bile robotu ayakta tutacaktır.
  4. Son olarak, Ki‘yi ayarlayın. Robot, Kp ve Kd ayarlanmış olsa bile açıldığında salınacak, ancak zaman içinde dengelenecektir. Doğru Ki değeri, robotun stabilize olması için gereken süreyi kısaltır.
shares